1 GOSUB7000
2 POKE53281,10
3 POKE53280,5
10 PRINT"[147]JEU DE YUM[146]"
20 PRINT"=========="
30 INPUT"NOMBRE DE JOUEURS (1 A 11) ";M
31 IFM<1ORM>11THENRUN
40 FORI=1TOM:PRINT"NOM DU JOUEUR"I;:INPUTM$(I)
50 IFLEN(M$(I))<6THENM$(I)=M$(I)+" ":GOTO50
60 NEXT
140 N=3:A$(1)="MONTEE":A$(2)="DESCENTE":A$(3)="LIBRE"
200 DIMZ$(12),C%(M,3,12),T%(M,3,12),JJ(36),G(12),X$(6),J(12),C$(3,12)
202 DIMCS(3),CX(3),S$(3),CZ(M,3),CT(3),W$(3),U$(3),LL(M),KK(M)
210 FORJ=1TO12:READZ$(J):NEXT
220 DATA"1","2","3","4","5","6"
222 DATAFULL  ,CARRE ,QUINTE,YUM   ,MAXI  ,MINI  ,
240 X$(1)="   [157][157][157] [209] [157][157][157]   ":X$(2)="[209]  [157][157][157]   [157][157][157]  [209]"
245 X$(3)="[209]  [157][157][157] [209] [157][157][157]  [209]":X$(6)="[209][209][209][157][157][157]   [157][157][157][209][209][209]"
250 X$(4)="[209] [209][157][157][157]   [157][157][157][209] [209]":X$(5)="[209] [209][157][157][157] [209] [157][157][157][209] [209]"
255 FORA=1TOM:LL(A)=12:KK(A)=1:NEXT
260 FORA=1TOM:FORJ=1TO12:FORI=1TON:C%(M,I,J)=0:T%(M,I,J)=0:NEXT:NEXT:NEXT
261 FORJJ=1TO36
262 FORA=1TOM
270 KM=5:L=5
275 FORH=1TO5:F(H)=H:NEXTH
280 FORK=1TO3:PRINT"[147]JOUEUR "M$(A):PRINT"COUP NUMERO"JJSPC(10);
285 PRINT"LANCER NUMERO"K""
287 FORW=1TO20:IFW>1THENPRINT"[145][145]"
288 T%=PEEK(143)
290 FORH=1TOL:B(F(H))=INT(6*RND(T%+H)+1):NEXTH
300 FORD=1TOKM:PRINT""X$(B(D))"[145][145]";:NEXTD:PRINT"":NEXTW
305 GOSUB2900
310 IFK=3THEN350
320 PRINT"COMBIEN DE DES REJOUEZ-VOUS?"
321 GETL$:IFL$<>"0"ANDL$<>"1"ANDL$<>"2"ANDL$<>"3"ANDL$<>"4"ANDL$<>"5"THEN321
322 IFL$="0"THEN350
323 IFL$="5"THEN340
330 L=VAL(L$):PRINT"QUEL(S) DE(S) ?":FORE=1TOL
331 GETF$
332 IFF$<>"1"ANDF$<>"2"ANDF$<>"3"ANDF$<>"4"ANDF$<>"5"THEN331
334 F(E)=VAL(F$)
335 NEXTE
340 NEXTK
350 PRINT"SUR QUEL TABLEAU JOUEZ-VOUS(M,D,L)?"
351 GETWZ$
352 IFWZ$<>"L"ANDWZ$<>"M"ANDWZ$<>"D"THEN351
355 IFWZ$="L"THEN400
360 IFWZ$="M"THEN364
362 IFWZ$="D"THEN369
363 PRINT"ERREUR":GOTO350
364 II=1:IFLL(A)<1GOTO363
365 Y$=Z$(LL(A)):IFLL(A)<7THENY$=MID$(Y$,4,1)
366 LL(A)=LL(A)-1:GOTO410
369 II=2:IFKK(A)>12THEN363
370 Y$=Z$(KK(A)):IFKK(A)<7THENY$=MID$(Y$,4,1)
372 KK(A)=KK(A)+1:GOTO410
400 II=3:PRINT"QUELLE COMBINAISON CHOISISSEZ-VOUS";:INPUTY$
410 FORG=1TO6:IFY$=MID$(Z$(G),4,1)THEN440
415 NEXT
420 FORG=7TO12:IFLEFT$(Y$,3)=LEFT$(Z$(G),3)THEN440
425 NEXT
430 PRINT"COMBINAISON INCONNUE":GOTO400
440 IFT%(A,II,G)=1THENPRINT"COMBINAISON DEJA CHOISIE":GOTO350
450 I=II:J=G:T%(A,I,J)=1:FORW=1TO5:R(W)=B(W):NEXT
460 FORV=1TO5
470 JM=1:MM=R(JM)
480 FORW=2TO5:IFR(W)<=MMTHEN500
490 JM=W:MM=R(W)
500 NEXTW
510 PO(V)=JM:R(JM)=-1
520 NEXTV
540 ONJGOSUB3300,3300,3300,3300,3300,3300,3410,3500,3610,3710,3810,3910,
580 NEXTA
585 NEXTJJ
599 FORA=1TOM:GOSUB3000
600 VV=CZ(A,1)+CZ(A,2)+CZ(A,3):SM=1032:MX=INT(100*VV/SM+.5)
610 PRINT"SCORE:"VV"MAXI.:"SM"TAUX:"STR$(MX)+"%[146]":GOSUB5000
615 NEXT
618 PRINT"VOULEZ-VOUS JOUER UNE AUTRE PARTIE ?"
619 GETA$:IFA$<>"N"ANDA$<>"O"THEN619
620 IFA$="O"THEN255
630 END
2800 PRINT"[147]JOUEUR "M$(A):PRINT"COUP NUMERO"JJSPC(10);
2810 PRINT"LANCER NUMERO"K""
2820 FORD=1TOKM:PRINT""X$(B(D))"[145][145]";:NEXTD
2900 PRINT:PRINT"VOULEZ-VOUS VOIR LA MARQUE (O/N)?"
2902 GETQ$
2905 IFQ$<>"O"ANDQ$<>"N"THEN2902
2910 IFQ$="N"THENRETURN
3000 PRINT"[147][207][183][183][183][183][183][183][208][183][183][183][183][183][183][183][208][183][183][183][183][183][183][183][183][207][183][183][183][183][183][183][208]"
3005 MM$(A)=""+LEFT$(M$(A),6)+"[146]"
3010 PRINT"[180]"MM$(A)"[170] MONTEE[170]DESCENTE[180]LIBRE [170]"
3020 PRINT"[204][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][175][204][175][175][175][175][175][175][186]"
3032 FORG=1TO6
3040 PRINT"[180]"Z$(G)"[167]";:FORI=1TON:OQ=C%(A,I,G):GOSUB6000:NEXTI:PRINT""
3045 NEXTG
3046 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
3050 FORI=1TON:CS(I)=0:FORG=1TO6:CS(I)=CS(I)+C%(A,I,G):NEXTG
3056 NEXTI
3057 G=13
3060 PRINT"[180]TOTAL1[167]";:FORI=1TON:OQ=CS(I):GOSUB6000:NEXTI:PRINT""
3065 FORI=1TON:T(I)=0:IFCS(I)>60THENT(I)=30
3068 NEXTI
3070 PRINT"[180]BONUS [167]";:FORI=1TON:OQ=T(I):GOSUB6000:NEXT:PRINT""
3075 FORI=1TON:CT(I)=CS(I)+T(I)
3078 NEXTI
3080 PRINT"[180]TOTAL2[167]";:FORI=1TON:OQ=CT(I):GOSUB6000:NEXTI:PRINT""
3090 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
3100 FORG=7TO12
3120 PRINT"[180]"Z$(G)"[170]";:FORI=1TON:OQ=C%(A,I,G):GOSUB6000:NEXTI:PRINT""
3130 NEXTG
3140 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
3150 FORI=1TON
3155 CX(I)=0
3160 FORG=7TO12:CX(I)=CX(I)+C%(A,I,G):NEXTG
3170 CZ(A,I)=CT(I)+CX(I)
3178 NEXTI
3180 PRINT"[180]TOTAL3[167]";:FORI=1TON:OQ=CZ(A,I):GOSUB6000:NEXTI:PRINT""
3190 PRINT"[204][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186]":IFJJ<36THENGOSUB5000
3195 IFJJ<37THENGOSUB2800
3200 RETURN
3300 FORV=1TO5:IFB(PO(V))=JTHENC%(A,I,J)=C%(A,I,J)+B(PO(V))
3315 NEXTV
3320 RETURN
3410 IFB(PO(1))=B(PO(2))ANDB(PO(2))=B(PO(3))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
3420 IFB(PO(1))=B(PO(2))ANDB(PO(3))=B(PO(4))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
3430 RETURN
3500 FORV=1TO5
3510 IFB(PO(1))=B(PO(2))ANDB(PO(2))=B(PO(3))ANDB(PO(3))=B(PO(4))THENC%(A,I,J)=30
3520 IFB(PO(2))=B(PO(3))ANDB(PO(3))=B(PO(4))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
3525 NEXTV
3530 RETURN
3610 FORV=1TO4:IFB(PO(V+1))=B(PO(V))-1THENNEXT
3615 IFV=5THENC%(A,I,J)=40
3620 RETURN
3710 FORV=1TO4:IFB(PO(V+1))=B(PO(V))THEN NEXTV:IFV=5THENC%(A,I,J)=50
3720 RETURN
3810 FORV=1TO5:C%(A,I,J)=C%(A,I,J)+B(PO(V)):NEXT
3820 IFT%(A,I,12)=1ANDC%(A,I,12)>=C%(A,I,J)THENC%(A,I,J)=0
3830 RETURN
3910 FORV=1TO5:C%(A,I,J)=C%(A,I,J)+B(PO(V)):NEXT
3920 IFT%(A,I,11)=1ANDC%(A,I,11)<=C%(A,I,J)THENC%(A,I,J)=0
3930 RETURN
5000 GETA$:IFA$=""THEN5000
5010 RETURN
6000 IFG=13ANDOQ=0THENPRINT"       [167]";:GOTO6020
6002 IFG=13THEN6010
6005 IFT%(A,I,G)=0THENPRINT"       [167]";:GOTO6020
6010 PRINTSPC(5-LEN(STR$(OQ)))OQSPC(1)"[167]";
6020 RETURN
7000 PRINT"[147]"
7070 POKE53280,2:POKE53281,11
7080 PRINT" YUM "
7090 PRINT"[144]PRESSEZ UNE TOUCHE"
8000 GETJ$:IFJ$=""THEN8000
8010 RETURN